AFEPLR Subroutine

private subroutine AFEPLR(J, LFLAG, PDROP, I, N, M, F, DF, NF)

Arguments

Type	Intent		Name
integer,	intent(in)	::	J
integer,	intent(in)	::	LFLAG
real(kind=r64),	intent(in)	::	PDROP
integer,	intent(in)	::	I
integer,	intent(in)	::	N
integer,	intent(in)	::	M
real(kind=r64),	intent(out)	::	F(2)
real(kind=r64),	intent(out)	::	DF(2)
integer,	intent(out)	::	NF
Calls

Help
Called By

Help
Source Code

AFEPLR
Source Code

      SUBROUTINE AFEPLR(J,LFLAG,PDROP,I,N,M,F,DF,NF)
!
          ! SUBROUTINE INFORMATION:
          !       AUTHOR         George Walton
          !       DATE WRITTEN   Extracted from AIRNET
          !       MODIFIED       Lixing Gu, 2/1/04
          !                      Revised the subroutine to meet E+ needs
          !       MODIFIED       Lixing Gu, 6/8/05
          !
          !       RE-ENGINEERED  na

          ! PURPOSE OF THIS SUBROUTINE:
          ! This subroutine solves airflow for a power law resistance airflow component

          ! METHODOLOGY EMPLOYED:
          ! na

          ! REFERENCES:
          ! na

          ! USE STATEMENTS:
          ! na

          IMPLICIT NONE    ! Enforce explicit typing of all variables in this routine


          ! SUBROUTINE ARGUMENT DEFINITIONS:
          INTEGER, INTENT(IN)  :: J     ! Component number
          INTEGER, INTENT(IN)  :: LFLAG ! Initialization flag.If = 1, use laminar relationship
          REAL(r64), INTENT(IN)     :: PDROP ! Total pressure drop across a component (P1 - P2) [Pa]
          INTEGER, INTENT(IN)  :: I     ! Linkage number
          INTEGER, INTENT(IN)  :: N     ! Node 1 number
          INTEGER, INTENT(IN)  :: M     ! Node 2 number
          INTEGER, INTENT(OUT) :: NF    ! Number of flows, either 1 or 2
          REAL(r64), INTENT(OUT)    :: F(2)  ! Airflow through the component [kg/s]
          REAL(r64), INTENT(OUT)    :: DF(2) ! Partial derivative:  DF/DP


          ! SUBROUTINE PARAMETER DEFINITIONS:
          ! na


          ! INTERFACE BLOCK SPECIFICATIONS
          ! na


          ! DERIVED TYPE DEFINITIONS
          ! na


          ! SUBROUTINE LOCAL VARIABLE DECLARATIONS:
         REAL(r64)     CDM, FL, FT
         REAL(r64)     RhozNorm, VisczNorm, expn, Ctl, coef
         INTEGER  CompNum

      ! FLOW:
      ! Crack standard condition: T=20C, p=101325 Pa and 0 g/kg
      CompNum = AirflowNetworkCompData(J)%TypeNum
      RhozNorm = PsyRhoAirFnPbTdbW(101325.0d0,20.0d0,0.0d0)
      VisczNorm = 1.71432d-5+4.828d-8*20.0d0
      expn = DisSysCompLeakData(CompNum)%FlowExpo
      coef = DisSysCompLeakData(CompNum)%FlowCoef

      IF(PDROP.GE.0.0d0) THEN
         coef = coef/SQRTDZ(N)
      ELSE
         coef = Coef/SQRTDZ(M)
      END IF

      NF = 1
      IF(LFLAG.EQ.1) THEN
        ! Initialization by linear relation.
        IF(PDROP.GE.0.0d0) THEN
          ctl = (RhozNorm/RHOZ(N))**(expn-1.0d0)*(VisczNorm/VISCZ(N))**(2.0d0*expn-1.0d0)
          DF(1) = Coef*RHOZ(N)/VISCZ(N)*ctl
        ELSE
          ctl = (RhozNorm/RHOZ(M))**(expn-1.0d0)*(VisczNorm/VISCZ(M))**(2.0d0*expn-1.0d0)
          DF(1) = Coef*RHOZ(M)/VISCZ(M)*ctl
        END IF
        F(1) = -DF(1)*PDROP
      ELSE
        ! Standard calculation.
        IF(PDROP.GE.0.0d0) THEN
          ! Flow in positive direction for laminar flow.
          ctl = (RhozNorm/RHOZ(N))**(expn-1.0d0)*(VisczNorm/VISCZ(N))**(2.0d0*expn-1.0d0)
          CDM = Coef*RHOZ(N)/VISCZ(N)*ctl
          FL = CDM*PDROP
          ! Flow in positive direction for turbulent flow.
          IF(expn .EQ. 0.5d0) THEN
            FT = Coef*SQRTDZ(N)*SQRT(PDROP)
          ELSE
            FT = Coef*SQRTDZ(N)*(PDROP**expn)
          END IF
        ELSE
          ! Flow in negative direction for laminar flow
          CDM = Coef*RHOZ(M)/VISCZ(M)
          FL = CDM*PDROP
          ! Flow in negative direction for turbulent flow
          IF(expn .EQ. 0.5d0) THEN
            FT = -Coef*SQRTDZ(M)*SQRT(-PDROP)
          ELSE
            FT = -Coef*SQRTDZ(M)*(-PDROP)**expn
          END IF
        END IF
        ! Select laminar or turbulent flow.
        IF(LIST.GE.4) WRITE(Unit21,901) ' plr: ',I,PDROP,FL,FT
        IF(ABS(FL).LE.ABS(FT)) THEN
          F(1) = FL
          DF(1) = CDM
        ELSE
          F(1) = FT
          DF(1) = FT*expn/PDROP
        END IF
      END IF
!
  901 FORMAT(A5,I3,6X,4E16.7)
      RETURN
      END SUBROUTINE AFEPLR
All Procedures
