CalcHnASHRAETARPExterior Function

private function CalcHnASHRAETARPExterior(TOutSurf, TAir, CosTilt) result(Hn)

Arguments

Type	Intent		Name
real(kind=r64),	intent(in)	::	TOutSurf
real(kind=r64),	intent(in)	::	TAir
real(kind=r64),	intent(in)	::	CosTilt

Return Value real(kind=r64)

Called By

Help

Source Code

CalcHnASHRAETARPExterior

Source Code

FUNCTION CalcHnASHRAETARPExterior(TOutSurf, TAir, CosTilt) RESULT(Hn)

          ! FUNCTION INFORMATION:
          !       AUTHOR         Linda K. Lawrie
          !       DATE WRITTEN   September 2003
          !       MODIFIED       na
          !       RE-ENGINEERED  na

          ! PURPOSE OF THIS FUNCTION:
          ! This function returns the natural convection piece of the
          ! exterior convection coefficient.


          ! METHODOLOGY EMPLOYED:
          ! Needs description, as appropriate.

          ! REFERENCES:
          !   1. ASHRAE.  1993.  ASHRAE Handbook - 1993 Fundamentals.  Atlanta.
          !   2. McClellan, T.M.  1996.  Investigation of a heat balance cooling load
          !   procedure with a detailed study of outside heat transfer parameters.
          !   M.S. Thesis, Department of Mechanical and Industrial Engineering,
          !   University of Illinois at Urbana-Champaign.
          !   3. ASHRAE Loads Toolkit

          ! USE STATEMENTS:
          ! na

  IMPLICIT NONE    ! Enforce explicit typing of all variables in this routine

          ! FUNCTION ARGUMENT DEFINITIONS:
  REAL(r64), INTENT(IN)  :: TOutSurf ! Exterior surface temperature
  REAL(r64), INTENT(IN)  :: TAir     ! Outdoor Air temperature
  REAL(r64), INTENT(IN)  :: CosTilt  ! Cosine of the Surface Tilt Angle (Angle between the ground outward normal and
                                ! the surface outward normal)
  REAL(r64)         :: Hn       ! Natural convective heat transfer coefficient,{W/(m2-K)}

          ! FUNCTION PARAMETER DEFINITIONS:
  REAL(r64), PARAMETER :: OneThird = (1.d0/3.d0)  ! 1/3 in highest precision

          ! INTERFACE BLOCK SPECIFICATIONS:
          ! na

          ! DERIVED TYPE DEFINITIONS:
          ! na

          ! FUNCTION LOCAL VARIABLE DECLARATIONS:
          ! na

  ! Notes: CosTilt > 0 = faces up (roof), CosTilt < 0 = faces down (floor),
  ! CosTilt=0 = vertical surface (wall)

  Hn=0.0d0

  IF (CosTilt == 0.0d0) THEN ! Vertical Surface

    Hn = 1.31d0*(ABS((TOutSurf-TAir))**OneThird)

  ELSE IF ( ((CosTilt < 0.0d0) .AND. (TOutSurf < TAir)) .OR. &
           ((CosTilt > 0.0d0) .AND. (TOutSurf > TAir)) ) THEN   ! Enhanced convection

    Hn = 9.482d0*(ABS((TOutSurf-TAir))**OneThird)/(7.238d0-ABS(CosTilt))

  ELSE IF ( ((CosTilt < 0.0d0) .AND. (TOutSurf > TAir)) .OR. &
           ((CosTilt > 0.0d0) .AND. (TOutSurf < TAir)) ) THEN   ! Reduced convection

    Hn = 1.810d0*(ABS((TOutSurf-TAir))**OneThird)/(1.382d0+ABS(CosTilt))

  END IF    ! Only other condition is TOutSurf=TAir, in which case there is no natural convection part.

  RETURN

END FUNCTION CalcHnASHRAETARPExterior

All Procedures