Nodes of different colours represent the following:
Solid arrows point from a parent (sub)module to the submodule which is descended from it. Dashed arrows point from a module being used to the module or program unit using it. Where possible, edges connecting nodes are given different colours to make them easier to distinguish in large graphs.
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| real(kind=r64), | intent(in) | :: | Height | |||
| real(kind=r64), | intent(in) | :: | TSurfIn | |||
| real(kind=r64), | intent(in) | :: | TAirIn |
Nodes of different colours represent the following:
Solid arrows point from a procedure to one which it calls. Dashed arrows point from an interface to procedures which implement that interface. This could include the module procedures in a generic interface or the implementation in a submodule of an interface in a parent module. Where possible, edges connecting nodes are given different colours to make them easier to distinguish in large graphs.
Nodes of different colours represent the following:
Solid arrows point from a procedure to one which it calls. Dashed arrows point from an interface to procedures which implement that interface. This could include the module procedures in a generic interface or the implementation in a submodule of an interface in a parent module. Where possible, edges connecting nodes are given different colours to make them easier to distinguish in large graphs.
FUNCTION HCInWindowStandardRatings(Height, TSurfIn, TAirIn) Result(hcin)
! FUNCTION INFORMATION:
! AUTHOR Bereket Nigusse
! DATE WRITTEN June 2013
! MODIFIED na
! RE-ENGINEERED na
! PURPOSE OF THIS FUNCTION:
! Return the inside convection coefficient for fenestration ratings.
! This procedure is adopted from WindowTempsForNominalCond routine.
!
!
! METHODOLOGY EMPLOYED:
! Uses ISO Standard 15099 method to calculate the inside surface
! convection coefficient for fenestration ratings.
! REFERENCES: na
!
! USE STATEMENTS:
!
USE Psychrometrics, ONLY: PsyRhoAirFnPbTdbW
IMPLICIT NONE ! Enforce explicit typing of all variables in this routine
! FUNCTION ARGUMENT DEFINITIONS:
REAL(r64), INTENT(IN) :: Height ! Window height, 1.0 m
REAL(r64), INTENT(IN) :: TSurfIn ! Inside surface temperature
REAL(r64), INTENT(IN) :: TAirIn ! Zone Air Temperature
!
! FUNCTION PARAMETER DEFINITIONS:
! na
! INTERFACE BLOCK SPECIFICATIONS
! na
! DERIVED TYPE DEFINITIONS
! na
! FUNCTION LOCAL VARIABLE DECLARATIONS:
REAL(r64) :: TmeanFilm ! mean film temperature
REAL(r64) :: TmeanFilmKelvin ! mean film temperature for property evaluation
REAL(r64) :: rho ! density of (apparently dry) air [kg/m3]
REAL(r64) :: Cp ! specific heat of air [J/kg-K]
REAL(r64) :: lambda ! thermal conductivity of air [W/m-K]
REAL(r64) :: mu ! dynamic viscosity of air [kg/m-s]
REAL(r64) :: RaH ! Rayleigh number for cavity height [ Non dim]
REAL(r64) :: tiltDeg ! glazing tilt in degrees
REAL(r64) :: sineTilt ! sine of glazing tilt
REAL(r64) :: Nuint ! Nusselt number for interior surface convection
REAL(r64) :: hcin ! interior surface convection coefficient
TiltDeg= 90.0D0
sineTilt = SIN(tiltDeg*DegToRadians) !degrees as arg
! Begin calculating for ISO 15099 method.
! mean film temperature
TmeanFilmKelvin = TAirIn + 0.25D0*(TSurfIn - TAirIn) ! eq. 133 in ISO 15099
TmeanFilm = TmeanFilmKelvin - 273.15D0
! the following properties are constants or linear relations for "standard" type reporting
rho = PsyRhoAirFnPbTdbW(101325.0D0, TmeanFilm, 0.0D0, 'HCInWindowStandardRatings') ! dry air assumption
lambda = 2.873D-3 + 7.76D-5 * TmeanFilmKelvin ! Table B.1 in ISO 15099
mu = 3.723D-6 + 4.94D-8 * TmeanFilmKelvin ! Table B.2 in ISO 15099
Cp = 1002.737D0 + 1.2324D-2 * TmeanFilmKelvin ! Table B.3 in ISO 15099
RaH = ( rho**2 * Height**3 * GravityConstant * Cp*(abs(TSurfIn - TAirIn)) ) &
/ (TmeanFilmKelvin * mu * lambda) ! eq 132 in ISO 15099
! eq. 135 in ISO 15099 (only need this one because tilt is 90 deg)
Nuint = 0.56D0*(RaH * sineTilt)**0.25D0
hcin = Nuint * lambda / Height
RETURN
END FUNCTION HCInWindowStandardRatings