Nodes of different colours represent the following:
Solid arrows point from a parent (sub)module to the submodule which is descended from it. Dashed arrows point from a module being used to the module or program unit using it. Where possible, edges connecting nodes are given different colours to make them easier to distinguish in large graphs.
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| integer, | intent(in) | :: | BoilerNum |
Nodes of different colours represent the following:
Solid arrows point from a procedure to one which it calls. Dashed arrows point from an interface to procedures which implement that interface. This could include the module procedures in a generic interface or the implementation in a submodule of an interface in a parent module. Where possible, edges connecting nodes are given different colours to make them easier to distinguish in large graphs.
Nodes of different colours represent the following:
Solid arrows point from a procedure to one which it calls. Dashed arrows point from an interface to procedures which implement that interface. This could include the module procedures in a generic interface or the implementation in a submodule of an interface in a parent module. Where possible, edges connecting nodes are given different colours to make them easier to distinguish in large graphs.
SUBROUTINE SizeBoiler(BoilerNum)
! SUBROUTINE INFORMATION:
! AUTHOR Fred Buhl
! DATE WRITTEN April 2002
! MODIFIED na
! RE-ENGINEERED na
! PURPOSE OF THIS SUBROUTINE:
! This subroutine is for sizing Boiler Components for which capacities and flow rates
! have not been specified in the input.
! METHODOLOGY EMPLOYED:
! Obtains hot water flow rate from the plant sizing array. Calculates nominal capacity from
! the hot water flow rate and the hot water loop design delta T.
! REFERENCES:
! na
! USE STATEMENTS:
USE DataSizing
USE DataPlant, ONLY: PlantLoop, PlantSizesOkayToFinalize
USE FluidProperties, ONLY: GetDensityGlycol, GetSpecificHeatGlycol
USE PlantUtilities, ONLY: RegisterPlantCompDesignFlow
USE ReportSizingManager, ONLY: ReportSizingOutput
USE OutputReportPredefined
IMPLICIT NONE ! Enforce explicit typing of all variables in this routine
! SUBROUTINE ARGUMENT DEFINITIONS:
INTEGER, INTENT(IN) :: BoilerNum
! SUBROUTINE PARAMETER DEFINITIONS:
! na
! INTERFACE BLOCK SPECIFICATIONS
! na
! DERIVED TYPE DEFINITIONS
! na
! SUBROUTINE LOCAL VARIABLE DECLARATIONS:
INTEGER :: PltSizNum ! Plant Sizing index corresponding to CurLoopNum
LOGICAL :: ErrorsFound ! If errors detected in input
CHARACTER(len=MaxNameLength) :: equipName ! Name of boiler object
REAL(r64) :: rho
REAL(r64) :: Cp
REAL(r64) :: tmpNomCap ! local nominal capacity cooling power
REAL(r64) :: tmpBoilerVolFlowRate ! local boiler design volume flow rate
PltSizNum = 0
ErrorsFound = .FALSE.
tmpNomCap = Boiler(BoilerNum)%NomCap
tmpBoilerVolFlowRate = Boiler(BoilerNum)%VolFlowRate
PltSizNum = PlantLoop(Boiler(BoilerNum)%LoopNum)%PlantSizNum
IF (Boiler(BoilerNum)%NomCap == AutoSize) THEN
IF (PltSizNum > 0) THEN
IF (PlantSizData(PltSizNum)%DesVolFlowRate >= SmallWaterVolFlow) THEN
rho = GetDensityGlycol(PlantLoop(Boiler(BoilerNum)%LoopNum)%FluidName, &
InitConvTemp, &
PlantLoop(Boiler(BoilerNum)%LoopNum)%FluidIndex, &
'SizeBoiler')
Cp = GetSpecificHeatGlycol(PlantLoop(Boiler(BoilerNum)%LoopNum)%FluidName, &
Boiler(BoilerNum)%TempDesBoilerOut, &
PlantLoop(Boiler(BoilerNum)%LoopNum)%FluidIndex, &
'SizeBoiler')
tmpNomCap = Cp * rho * Boiler(BoilerNum)%SizFac &
* PlantSizData(PltSizNum)%DeltaT &
* PlantSizData(PltSizNum)%DesVolFlowRate
IF (PlantSizesOkayToFinalize) Boiler(BoilerNum)%NomCap = tmpNomCap
ELSE
tmpNomCap = 0.d0
IF (PlantSizesOkayToFinalize) Boiler(BoilerNum)%NomCap = tmpNomCap
END IF
IF (PlantSizesOkayToFinalize) CALL ReportSizingOutput('Boiler:HotWater', Boiler(BoilerNum)%Name, &
'Nominal Capacity [W]', Boiler(BoilerNum)%NomCap)
ELSE
CALL ShowSevereError('Autosizing of Boiler nominal capacity requires a loop Sizing:Plant object')
CALL ShowContinueError('Occurs in Boiler object='//TRIM(Boiler(BoilerNum)%Name))
ErrorsFound = .TRUE.
END IF
END IF
IF (Boiler(BoilerNum)%VolFlowRate == AutoSize) THEN
IF (PltSizNum > 0) THEN
IF (PlantSizData(PltSizNum)%DesVolFlowRate >= SmallWaterVolFlow) THEN
tmpBoilerVolFlowRate = PlantSizData(PltSizNum)%DesVolFlowRate * Boiler(BoilerNum)%SizFac
IF (PlantSizesOkayToFinalize) Boiler(BoilerNum)%VolFlowRate = tmpBoilerVolFlowRate
ELSE
tmpBoilerVolFlowRate = 0.0d0
IF (PlantSizesOkayToFinalize) Boiler(BoilerNum)%VolFlowRate = tmpBoilerVolFlowRate
END IF
IF (PlantSizesOkayToFinalize) CALL ReportSizingOutput('Boiler:HotWater', Boiler(BoilerNum)%Name, &
'Design Water Flow Rate [m3/s]', &
Boiler(BoilerNum)%VolFlowRate)
ELSE
CALL ShowSevereError('Autosizing of Boiler design flow rate requires a loop Sizing:Plant object')
CALL ShowContinueError('Occurs in Boiler object='//TRIM(Boiler(BoilerNum)%Name))
ErrorsFound = .TRUE.
END IF
END IF
CALL RegisterPlantCompDesignFlow(Boiler(BoilerNum)%BoilerInletNodeNum,tmpBoilerVolFlowRate)
IF (PlantSizesOkayToFinalize) THEN
!create predefined report
equipName = Boiler(BoilerNum)%Name
CALL PreDefTableEntry(pdchMechType,equipName,'Boiler:HotWater')
CALL PreDefTableEntry(pdchMechNomEff,equipName,Boiler(BoilerNum)%Effic)
CALL PreDefTableEntry(pdchMechNomCap,equipName,Boiler(BoilerNum)%NomCap)
ENDIF
IF (ErrorsFound) THEN
CALL ShowFatalError('Preceding sizing errors cause program termination')
END IF
RETURN
END SUBROUTINE SizeBoiler