ComputeNominalUwithConvCoeffs Function

public function ComputeNominalUwithConvCoeffs(numSurf, isValid) result(NominalUwithConvCoeffs)

Uses:
DataSurfaces

Arguments

Type	Intent	Optional	Attributes		Name
integer,	intent(in)			::	numSurf
logical,	intent(out)			::	isValid

Return Value real(kind=r64)

Source Code

FUNCTION ComputeNominalUwithConvCoeffs(numSurf,isValid) RESULT(NominalUwithConvCoeffs)

          ! SUBROUTINE INFORMATION:
          !       AUTHOR         Jason Glazer
          !       DATE WRITTEN   September 2013
          !       MODIFIED       na
          !       RE-ENGINEERED  na

          ! PURPOSE OF THIS SUBROUTINE:
          ! Calculate Nominal U-value with convection/film coefficients for reporting by
          ! adding on prescribed R-values for interior and exterior convection coefficients
          ! as found in ASHRAE 90.1-2004, Appendix A. Used in EIO and tabular reports.
          !
          ! ASHRAE 90.1-2004 Section A9.4.1 shows the following:
          !      R-value Condition
          !      All exterior conditions                        IP: 0.17  SI: 0.0299
          !      All semi-exterior surfaces                     IP: 0.46  SI: 0.0810
          !      Interior horizontal surfaces, heat flow up     IP: 0.61  SI: 0.1074
          !      Interior horizontal surfaces, heat flow down   IP: 0.92  SI: 0.1620
          !      Interior vertical surfaces                     IP: 0.68  SI: 0.1198
          ! This section shows the same value in 90.1-2007 and 90.2-2010

          ! METHODOLOGY EMPLOYED:
          ! na

          ! REFERENCES:
          ! na

          ! USE STATEMENTS:
  USE DataSurfaces, ONLY: Surface, SurfaceClass_Wall, SurfaceClass_Floor, &
                          SurfaceClass_Roof, ExternalEnvironment,&
                          Ground,GroundFCfactorMethod, SurfaceClass_Door

  IMPLICIT NONE    ! Enforce explicit typing of all variables in this routine

          ! SUBROUTINE ARGUMENT DEFINITIONS:
  INTEGER, INTENT(IN)   :: numSurf    ! index for Surface array.
  LOGICAL, INTENT(OUT)  :: isValid    ! returns true if result is valid
  REAL(r64)             :: NominalUwithConvCoeffs !return value
          ! SUBROUTINE PARAMETER DEFINITIONS:
          ! na

          ! INTERFACE BLOCK SPECIFICATIONS:
          ! na

          ! DERIVED TYPE DEFINITIONS:
          ! na

          ! SUBROUTINE LOCAL VARIABLE DECLARATIONS:

  REAL(r64) :: insideFilm
  REAL(r64) ::  outsideFilm


  isValid = .TRUE.
  ! exterior conditions
  SELECT CASE (Surface(numSurf)%ExtBoundCond)
    CASE (ExternalEnvironment)
      outsideFilm = 0.0299387d0 ! All exterior conditions
    CASE (Ground,GroundFCfactorMethod)
      outsideFilm = 0.0d0       ! No outside film when underground
    CASE DEFAULT
      IF (Surface(numSurf)%ExtBoundCond > 0) THEN !interzone partition
        !use companion surface in adjacent zone
        SELECT CASE (Surface(Surface(numSurf)%ExtBoundCond )%class)
        CASE (SurfaceClass_Wall,SurfaceClass_Door)  ! Interior:  vertical, still air, Rcin = 0.68 ft2-F-hr/BTU
          outsideFilm = 0.1197548d0
        CASE (SurfaceClass_Floor) ! Interior:  horizontal, still air, heat flow downward, Rcin = 0.92 ft2-F-hr/BTU
          outsideFilm = 0.1620212d0
        CASE (SurfaceClass_Roof)  ! Interior:  horizontal, still air, heat flow upward, Rcin = 0.61 ft2-F-hr/BTU
          outsideFilm = 0.1074271d0
        CASE DEFAULT
          outsideFilm = 0.0810106d0 ! All semi-exterior surfaces
        END SELECT
      ELSE
        outsideFilm = 0.0810106d0 ! All semi-exterior surfaces
      ENDIF
  END SELECT
  ! interior conditions
  IF (NominalU(Surface(numSurf)%Construction) > 0.0d0) THEN
    SELECT CASE (Surface(numSurf)%class)
      CASE (SurfaceClass_Wall,SurfaceClass_Door)  ! Interior:  vertical, still air, Rcin = 0.68 ft2-F-hr/BTU
        insideFilm = 0.1197548d0
      CASE (SurfaceClass_Floor) ! Interior:  horizontal, still air, heat flow downward, Rcin = 0.92 ft2-F-hr/BTU
        insideFilm = 0.1620212d0
      CASE (SurfaceClass_Roof)  ! Interior:  horizontal, still air, heat flow upward, Rcin = 0.61 ft2-F-hr/BTU
        insideFilm = 0.1074271d0
      CASE DEFAULT
        insideFilm = 0.0d0
        outsideFilm = 0.0d0
    END SELECT
    NominalUwithConvCoeffs = 1.0d0 / (insideFilm + (1.0d0 / NominalU(Surface(numSurf)%Construction)) + outsideFilm)
  ELSE
    isValid = .FALSE.
    NominalUwithConvCoeffs = NominalU(Surface(numSurf)%Construction)
  END IF
END FUNCTION ComputeNominalUwithConvCoeffs

All Procedures

ComputeNominalUwithConvCoeffs Function

Source Code

All Procedures

public function ComputeNominalUwithConvCoeffs(numSurf, isValid) result(NominalUwithConvCoeffs)

Uses:

Arguments

Return Value real(kind=r64)

Calls

Called By

Source Code

Source Code

All Procedures