| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| integer, | intent(in) | :: | SurfNum | |||
| real(kind=r64), | intent(in) | :: | SurfaceTemperature | |||
| real(kind=r64), | intent(in) | :: | ZoneMeanAirTemperature |
Nodes of different colours represent the following:
Solid arrows point from a procedure to one which it calls. Dashed arrows point from an interface to procedures which implement that interface. This could include the module procedures in a generic interface or the implementation in a submodule of an interface in a parent module. Where possible, edges connecting nodes are given different colours to make them easier to distinguish in large graphs.
Nodes of different colours represent the following:
Solid arrows point from a procedure to one which it calls. Dashed arrows point from an interface to procedures which implement that interface. This could include the module procedures in a generic interface or the implementation in a submodule of an interface in a parent module. Where possible, edges connecting nodes are given different colours to make them easier to distinguish in large graphs.
SUBROUTINE CalcASHRAESimpleIntConvCoeff(SurfNum,SurfaceTemperature,ZoneMeanAirTemperature)
! SUBROUTINE INFORMATION:
! AUTHOR Rick Strand
! DATE WRITTEN August 2000
! MODIFIED na
! RE-ENGINEERED na
! PURPOSE OF THIS FUNCTION:
! This subroutine calculates the interior convection coefficient for a surface.
! METHODOLOGY EMPLOYED:
! The convection coefficients are taken directly from the TARP Reference Manual. TARP calculated
! its coefficients using the surface conductances for e=0.9 found in ASHRAE Handbook of Fundamentals
! 1985 in Table 1 on p. 23.2, but subtracted off the radiative component which was estimated at
! 1.02 * 0.9 = 0.918 BTU/h-ft2-F. Coefficients were then converted to SI units to yield the values
! in this subroutine.
! REFERENCES:
! 1. Walton, G. N. 1983. Thermal Analysis Research Program (TARP) Reference Manual,
! NBSSIR 83-2655, National Bureau of Standards, "Surface Inside Heat Balances", pp 79.
! 2. ASHRAE Handbook of Fundamentals 1985, p. 23.2, Table 1.
! USE STATEMENTS:
! na
IMPLICIT NONE ! Enforce explicit typing of all variables in this routine
! SUBROUTINE ARGUMENT DEFINITIONS:
INTEGER, INTENT(IN) :: SurfNum ! surface number for which coefficients are being calculated
REAL(r64), INTENT(IN) :: SurfaceTemperature ! Temperature of surface for evaluation of HcIn
REAL(r64), INTENT(IN) :: ZoneMeanAirTemperature ! Mean Air Temperature of Zone
! SUBROUTINE PARAMETER DEFINITIONS:
! na
! INTERFACE BLOCK SPECIFICATIONS:
! na
! DERIVED TYPE DEFINITIONS:
! na
! SUBROUTINE LOCAL VARIABLE DECLARATIONS:
REAL(r64) :: DeltaTemp ! Temperature difference between the zone air and the surface
IF (ABS(Surface(SurfNum)%CosTilt) >= 0.3827d0) THEN ! Recalculate HConvIn
DeltaTemp = ZoneMeanAirTemperature - SurfaceTemperature
! Set HConvIn using the proper correlation based on DeltaTemp and Cosine of the Tilt of the Surface
IF (ABS(Surface(SurfNum)%CosTilt) >= 0.9239d0) THEN ! Horizontal Surface
IF (DeltaTemp*Surface(SurfNum)%CosTilt < 0.0d0) THEN ! Horizontal, Reduced Convection
HConvIn(SurfNum) = 0.948d0
ELSEIF (DeltaTemp*Surface(SurfNum)%CosTilt == 0.0d0) THEN ! Vertical Surface
HConvIn(SurfNum) = 3.076d0
ELSEIF (DeltaTemp*Surface(SurfNum)%CosTilt > 0.0d0) THEN ! Horizontal, Enhanced Convection
HConvIn(SurfNum) = 4.040d0
END IF
ELSE ! Tilted Surface
IF (DeltaTemp*Surface(SurfNum)%CosTilt < 0.0d0) THEN ! Tilted, Reduced Convection
HConvIn(SurfNum) = 2.281d0
ELSEIF (DeltaTemp*Surface(SurfNum)%CosTilt == 0.0d0) THEN ! Vertical Surface
HConvIn(SurfNum) = 3.076d0
ELSEIF (DeltaTemp*Surface(SurfNum)%CosTilt > 0.0d0) THEN ! Tilted, Enhanced Convection
HConvIn(SurfNum) = 3.870d0
END IF
END IF ! ...end of correlation selection IF-THEN block
END IF ! ...end of HConvIn recalculation IF-THEN block
! Establish some lower limit to avoid a zero convection coefficient (and potential divide by zero problems)
IF (HConvIn(SurfNum) < LowHConvLimit) HConvIn(SurfNum) = LowHConvLimit
RETURN
END SUBROUTINE CalcASHRAESimpleIntConvCoeff